DataTables

Now added .net project file: http://alex.gizmosurge.com/wp/wp-content/plugins/download-monitor/download.php?id=3


PART 1

Hello,
I was recently tasked to create a VB.NET website (I know...vb...argg!). The goal was to consume xml files on the server and present them to the end user via the website where they can search,print....etc. I ran across DataTables and became instantly in love with them. Here is quick excerpt on what I did. The title of the thread outlines my goals.

XML - Source Data

Consideration: The data object will contain is base information and include multiples of addresses/phones/staff

<agency>
    <name>Bob's Agency</name>
    <account>12341234214</account>
    <expirationDate>9/4/2011 12:00:00 AM</expirationDate>
    <addresses>
      <address>
        <addressType>Mailing</addressType>
        <address1>1234 Main Street</address1>
        <address2></address2>
        <city>New Orleans</city>
        <state>LA</state>
        <zip>70112</zip>
        <county>New Orleans</county>
      </address>
   </addresses>
   <phones>
      <phone>
        <phoneType>Home</phoneType>
        <number>(800) xxx-xxxx</number>
      </phone>
      <phone>
        <phoneType>Office</phoneType>
        <number>(800) xxx-xxxx</number>
      </phone>
    </phones>
    <staff>
      <person>
        <manager>0</manager>
        <id>7549</id>
        <fname>Peter</fname>
        <lname>Gibbons</lname>
      </person>
      <person>
        <manager>1</manager>
        <id>D0Rk</id>
        <fname>Bill</fname>
        <lname>Lumbergh</lname>
      </person>
    </staff>
  </agency>

Class Object

Consideration: I decided to go with a class object that will be painted directly onto the html page. I wanted to keep it simple and I prefer to call objects directly. I use LINQ to pull the root nodes but the beauty of LINQ is the ability to include WHERE/SORT/DISTINCT.
**I added a Locations property that will get all unique City/State combinations so I can display that on the DataTable for searching capabilities
**If there is a typo then my apologies as I have to edit a few items prior to posting

Public Class Entity_Agency

    Private _name As String
    Private _account As String
    Private _expirationdate As Date
    Private _locations as String                                       'This is a bonus item to list all distinct locations on the DataTable

    Private _addresses As List(Of Address)
    Private _phones As List(Of Phone)
    Private _staffing As List(Of Person)

    Structure Address
        Public Type As String
        Public Address1 As String
        Public Address2 As String
        Public City As String
        Public State As String
        Public Zip As String
        Public County As String
    End Structure

    Structure Phone
        Public Type As String
        Public Number As String
    End Structure

    Structure Person
        Public Manager As Integer
        Public StaffID As String
        Public FirstName As String
        Public LastName As String
    End Person

    ReadOnly Property Name() As String
        Get
            Return _name
        End Get
    End Property

  ...........skipping a few properties.....

    ReadOnly Property Addresses() As List(Of Address)
        Get
            Return _addresses
        End Get
    End Property

    ReadOnly Property Phones() As List(Of Phone)
        Get
            Return _phones
        End Get
    End Property

    ReadOnly Property Staffing() As List(Of Person)
        Get
            Return _staffing
        End Get
    End Property


    Public Sub New(ByVal Name As String, ByVal Account As String, _
                    ByVal ExpirationDate As Date, ByVal Locations As String, _
                    ByVal Addresses As List(Of Address), _
                    ByVal Phones As List(Of Phone), _
                    ByVal Staffing As List(Of Person))

        _name = Name
        _account = Account
        _expirationdate = ExpirationDate
        _locations = Locations
        _addresses = Addresses
        _phones = Phones
        _staffing = Staffing

    End Sub


    Public Function GetAgencies(ByVal xmlFile As String) As Collection

        Dim myAgencies As New Collection
        Dim myDoc As XDocument
        myDoc = XDocument.Load(xmlFile)
        Dim myQuery = From myXE In myDoc.Descendants.Elements("agency")

        For Each myXE As XElement In myQuery

            'Get all addresses associated to agency
            Dim myAddressList As New List(Of Address)                          'declare list container
            Dim myLocations As String = ""                                              'collects distinct city/state combo
            For Each xeAddressItem As XElement In myXE.<addresses>.<address>            'iterate through each xml address
                
                Dim myAddressItem As Address
                myAddressItem.Type = xeAddressItem.<addressType>.Value
                myAddressItem.Address1 = xeAddressItem.<address1>.Value
                myAddressItem.Address2 = xeAddressItem.<address2>.Value
                myAddressItem.City = xeAddressItem.<city>.Value
                myAddressItem.State = xeAddressItem.<state>.Value

                Dim tempCityState As String = xeAddressItem.<city>.Value + ", " + xeAddressItem.<state>.Value
                If (myLocations.Contains(tempCityState) = False) Then
                    If (myLocations = "") Then
                        myLocations = tempCityState
                    Else
                        myLocations += "<br/>" + tempCityState                'added <br/> to keep each city/state combo own line
                    End If
                End If

                myAddressItem.Zip = xeAddressItem.<zip>.Value
                myAddressItem.County = xeAddressItem.<county>.Value
                myAddressList.Add(myAddressItem)
            Next

            'Get all phonenumbers associated to agency
           
            Dim myPhoneList As New List(Of Phone)                                       'declare list container

            For Each xePhoneItem As XElement In myXE.<phones>.<phone>                   'iterate through each xml address
                Dim myPhoneItem As Phone
                myPhoneItem.Type = xePhoneItem.<phoneType>.Value
                myPhoneItem.Number = xePhoneItem.<number>.Value
                myPhoneList.Add(myPhoneItem)
            Next

            'Get all agency staffing
     
            Dim myStaffList As New List(Of Person)                                   'declare list container

            Dim myPersonQuery= From personXE In myXE.<staff>.<person> Order By personXE .<manager>.Value Descending

            For Each xePersonItem As XElement In myPersonQuery
                Dim myPersonItem As Person
                myPersonItem.Manager = xePersonItem.<manager>.Value
                myPersonItem.StaffID = xePersonItem.<id>.Value
                myPersonItem.FirstName = xePersonItem.<fname>.Value
                myPersonItem.LastName = xePersonItem.<lname>.Value
                myStaffList.Add(myPersonItem)
            Next

            'Put everything into my class object now
            myAgencies.Add( _
                    New Entity_Agency( _
                        myXE.<name>.Value, _
                        myXE.<account>.Value, _
                        myXE.<expirationDate>.Value, _
                        myLocations, _
                        myAddressList, _
                        myPhoneList, _
                        myStaffList))

        Next
        Return myAgencies
    End Function
End Class